ターボハムログ 5QSO用印刷マクロ

[小ネタ]ターボハムログ 5QSO用印刷マクロ

　QSLカード1枚に5件のQSOを記載できるハムログ用印刷マクロ２種類です。
移動局を呼ぶことが多いので交信ごとに相手局の移動地を記載できるようにしました。

自局移動地は交信毎のRemarks2欄に特定の書式で書いておく必要がありますので、ドロップダウンメニューに仕込んでおくと便利です。　
記述方法は「1-1自局が移動の場合」記事中に説明があります

スタイルその１
　データ欄下部に自局の運用地を大きく１つだけ表示するスタイルです。
運用地毎に分けて印刷しないといけないので、移動しないか移動しても１か所で多くサービスする運用に向きます。

スタイルその２
　交信毎に自局の移動地を表示するスタイルです。
自局運用地を気にせずに印刷できますが自局運用地の文字は小さくなります

１-1　自局運用地を大きく１つだけ表示するスタイル

１）1枚のカードに5件までのQSOを記載で
　　きます
２）交信毎の相手局移動地を記載します
＊/QRP等、ハムログの仕様で移動と見
　做されない場合は記載できません
＊相手局の/以降が4文字以上の場合は
　移動地の表記と重なります
　ログQTH欄の前方に空白を入れて回避
　できます
３）JST/UTCを判別し記載します
４）データ系のレポートに"dB"を付記しま
　　す
５）レポート欄は文字数により印字位置
　　を調整しています
６）モード欄は文字数により文字サイズと
　　印字位置を調整しています
７）QSL No.は初出データのものです
８）Rmks欄は印刷画面のコメントを表示
　　するようにしました
９）署名(モザイクの部分)はBMP画像です
　　別途用意してください

マネージャ経由の転送の場合は
To Radioの下に交信相手局のコールサイ
ン、"via"と転送枠内にマネージャのコール
サインが表示されます

条件として
　ハムログに以下の記載があること

　・QSL SENDが　"M"
　・Remarks1に"@(転送先ｺｰﾙｻｲﾝ)"

＊転送枠が1つしかないので
　　交信毎に転送先が異なる場合には対応
　　できません

自局が移動の場合
Remarks2欄に以下の記載があれば移動とみなして自局コールサインの後に"/(数字)と移動地を表示します

記載方法
　%/(半角数字0～9またはP) 移動地等%

　記述例（左の場合)
　%/1 相模原市緑区　JCC111001%

＊マクロでは"%/(数字又はP)があれば移
　動しているとみなします
＊"移動"の文字は自動付記されます
＊自局の運用地はQSLの記載範囲で初出
　の1か所しか表記できません
　自局の移動地ごとに印刷を分けて行う
　ようにしてください

2ポイント運用には→こちらが便利

１－２　印刷マクロの内容

　マクロファイル"5QSO.QSL"はここから最新版をダウンロードできます。
　※最新版は少しデザインを変更、コマンドの重複を整理したので当初の記事からは
　　一部変更されています
　△交信データの区切り線が印刷できなかったので修正しました '23/12/09
　* このマクロの使用は自己責任でお願いします
　* コールサイン、住所、リグなどを修正してお使いください
　* このマクロおよびハムログの使用についてサポートは行いません
　* 利益を目的とした頒布や商用利用は禁止します

　マクロは大きく
　　１．　転送枠、データ枠、データタイトルなどの基本部分
　　２．　自局リグ、アンテナ、名前などの共通部分
　　３．　自局QTH
　　４．　転送先、交信データ
　に別れています。
　個人用に変更するには赤と青文字部分を修正してください

#SetXY -6, -25 ;PrintPack用紙、LBP6230用の設定
#Size 1000, 1480
#FontName="HAM 明朝 Light"
#FontColor=0x00000000
;
;=====転送枠・データ枠・項目タイトル印刷=====
;
#FontSize=13
#FontStyle=1
#Print 35, 60, "To Radio"
#FontStyle=0

;JARL転送枠印刷
#LineS 2, 0, 255 ;JARL転送枠赤色幅2の実線指定
#LineR 350, 95, 423, 190 ;オリジナルより各box始点Y-2、終点X+3
#LineR 440, 95, 513, 190
#LineR 530, 95, 603, 190
#LineR 620, 95, 693, 190
#LineR 710, 95, 783, 190
#LineR 800, 95, 873, 190
;
#FontName="ＭＳ明朝"
#FontSize=12
#Print 10, 220, "Confirming Our QSO"

;データ枠、タイトル枠
#LineS 1, 0, 0
#LineR 8, 260, 901, 908
#LineX 8, 300, 894
#FontSize=10
#Print 140, 263, "DATE"
#Print 355, 263, "TIME"
#Print 535, 263, "RPT"
#Print 663, 263, "BAND"
#Print 790, 263, "MODE"

;交信データ区切り線
#LineS 1,1,0 ;←△ここを修正 '23/12/09
#LineX 25,438,850
#LineX 25,554,850
#LineX 25,670,850
#LineX 25,786,850

;データタイトル
#FontSize=8
#Print 30, 308, "Year"
#Print 128, 308, "Month"
#Print 243, 308, "Day"
#Print 700, 308, "MHz"
#Print 788, 308, "2Way"
;
;=====自局リグ・コールサイン・QTHなど印刷=====
;
;TX・アンテナ印刷常置・設置場所用
#FontSize=10
#Print 20, 912, "TX :JST-245,IC-7300 / IC-7300M,FT-991AM"
#Print 20, 945, "ANT:[HF]Dipole [6m]Yagi 5elx2 / F9FT"
;
;印刷画面のコメントをRemarks欄印刷
;Rmks1欄の初出コメント印刷するときは !Co→ !R1
#FontSize=10
#Print 20, 998, "Rmks:!Co"
#LineS 1, 0, 0
#LineX 15, 1038, 860 ; RMKSに下線
;
; 署名（BMPファイル）印刷　(文字欠け防止のため先に印刷)
;
#Bmp 580, 1290, 220, 140, "c:\hamlogw\sign.bmp"

;
; 自局コール/n、住所、名前、移動地印刷
;
;英文QTH/OP印刷
;

#Print 50, 1052, "Home：Minami-ku, Sagamihara, Kanagawa, JAPAN"
#Print 85, 1102, "OP：MIZUKAMI, Takashi (Taka)"
#FontName="HG丸ｺﾞｼｯｸM-PRO"
#FontSize=24
#Print 100, 1160, "ＪＡ１ＶＺＶ" ; 自局コールを大きく印刷
;
; 自局が移動運用の場合コールの後に「/(数字)」、移動地を印刷
;
? RmStr "%/1" ; /1追加印刷
#Print 610, 1160, "/1"
? End

? RmStr "%/2" ; /2追加印刷
#Print 610, 1160, "/2"
? End

? RmStr "%/3" ; /3追加印刷
#Print 610, 1160, "/3"
? End

? RmStr "%/4" ; /4追加印刷
#Print 610, 1160, "/4"
? End

? RmStr "%/5" ; /5追加印刷
#Print 610, 1160, "/5"
? End

? RmStr "%/6" ; /6追加印刷
#Print 610, 1160, "/6"
? End

? RmStr "%/7" ; /7追加印刷
#Print 610, 1160, "/7"
? End

? RmStr "%/8" ; /8追加印刷
#Print 610, 1160, "/8"
? End

? RmStr "%/9" ; /9追加印刷
#Print 610, 1160, "/9"
? End

? RmStr "%/0" ; /0追加印刷
#Print 610, 1160, "/"
#FontName="HAM 明朝 Light"
#Print 650, 1160, "0"
? End

? RmStr "%/P" ; /P追加印刷
#Print 610, 1160, "/P"
? End

;
; 自局QTHを印刷
;
#FontName="ＭＳ明朝"
#FontSize=10

? RmStr "%/" ;Remarksra欄に %/ ・・・%の記述があれば
#Print 120, 1262, "JA1VZV!R2" ;自局移動地を印刷
? RmStr! "%/" ;なければ設(常)置場所を印刷
#Print 80, 1262, "神奈川県相模原市南区　JCC#111003, GL:PM95QL"
#Print 280, 1312, "OP : 水上　高志"

;=====交信データ印刷=====

#FontName="HAM 明朝 Light"

;JARL転送先印刷
#FontSize = 20
#Print 350, 110, "!C1 " ;JARL転送先１文字目
#Print 440, 110, "!C2 " ;JARL転送先２文字目
#Print 530, 110, "!C3 " ;JARL転送先３文字目
#Print 620, 110, "!C4 " ;JARL転送先４文字目
#Print 710, 110, "!C5 " ;JARL転送先５文字目
#Print 800, 110, "!C6 " ;JARL転送先６文字目

?QslM ; マネージャ経由の場合のみ
#FontSize=14
#FontStyle=0
#Print 28, 137, "!cp" ; 相手局コールサイン(最大10文字)印刷
#FontSize = 9
#Print 300, 155, "via"
#LineS 1, 0, 0
#LineX 25, 190, 270 ; 相手局コールサインの下にライン
? End

#FontName="ＭＳ明朝"
#FontSize=10
#Print 770, 225, "#!NO" ;初出QSL No.印刷

;**交信データ1行目**

#FontName="HAM 明朝 Light"
#FontSize=11
#Print 20, 342, "!cp" ;相手局コールサイン印刷
#FontName="ＭＳ明朝"
? DXST! ;相手局が海外局ではなく
? Potbl ;移動運用で
? Space! "!QT" ;QTHが入力されていたら
#FontSize=9
#Print 240, 348, "!QT 移動" ;相手局のQTHを印刷
? End

#FontSize=11
#Print 20, 396, "'!Dy" ;交信年
#Print 120, 396, "!DJ." ;交信月
#Print 240, 396, "!Dd" ;交信日
#Print 330, 396, "!TH:!TM" ;交信時、分
#Print 660, 396, "!FR" ;交信周波数帯

? ndata7 "AM,FM,SSB,C4FM" ;レポートが2文字のモードは
#Print 535, 396, " !HR" ;Hisレポートの前に１スペース挿入
? ndata7! "AM,FM,SSB,C4FM" ;他のモードは
#Print 535, 396, "!HR" ;Hisレポートそのまま印刷
;
;データモードはレポート欄に"dB"印刷
;
? ndata7 "FT8,FT4,Q65,MSK144,JT65"
#FontSize=8
#Print 603, 396, "dB"
? End
;
;JST/UTC印刷
;
#FontSize=10
? UTC!
#Print 440, 400, "JST"
? UTC
#Print 440, 400, "UTC"
;
; モード別調整印刷
;
#FontSize=10
? ndata7 "CW,AM,FM,SSB,FT8,FT4,Q65" ;2-3文字
#Print 777, 396, " !MD"
? ndata7 "C4FM,SSTV,RTTY,JT44,JT65,JT6M" ;4文字
#Print 777, 396, " !MD"
? ndata7 "PSK31,PSK63" ;5文字
#Print 777, 396, "!MD"
? ndata7 "MFSK16,FSK441,MSK144" ;6文字
#FontSize=9
#Print 777, 396, "!MD"
? End

;**交信データ2行目**

#Readj *992 ;同じコールサインでなければ*992へ

#FontName="HAM 明朝 Light"
#FontSize=11
#Print 20, 458, "!cp" ;相手局コールサイン印刷
#FontName="ＭＳ明朝"
? DXST! ;相手局が海外局ではなく
? Potbl ;移動運用で
? Space! "!QT" ;QTHが入力されていたら
#FontSize=9
#Print 240, 464, "!QT 移動" ;相手局のQTHを印刷
? End

#FontSize=11
#Print 20, 512, "'!Dy" ;交信年
#Print 120, 512, "!DJ." ;交信月
#Print 240, 512, "!Dd" ;交信日
#Print 330, 512, "!TH:!TM" ;交信時、分
#Print 660, 512, "!FR" ;交信周波数帯

? ndata7 "AM,FM,SSB,C4FM" ;レポートが2文字のモードは
#Print 535, 512, " !HR" ;Hisレポートの前に１スペース挿入
? ndata7! "AM,FM,SSB,C4FM" ;他のモードは
#Print 535, 512, "!HR" ;Hisレポートそのまま印刷
;
;データモードはレポート欄に"dB"印刷
;
? ndata7 "FT8,FT4,Q65,MSK144,JT65"
#FontSize=8
#Print 603, 512, "dB"
? End
;
;JST/UTC印刷
;
#FontSize=10
? UTC!
#Print 440, 516, "JST"
? UTC
#Print 440, 516, "UTC"
;
; モード別調整印刷
;
#FontSize=10
? ndata7 "CW,AM,FM,SSB,FT8,FT4,Q65" ;2-3文字
#Print 777, 512, " !MD"
? ndata7 "C4FM,SSTV,RTTY,JT44,JT65,JT6M" ;4文字
#Print 777, 512, " !MD"
? ndata7 "PSK31,PSK63" ;5文字
#Print 777, 512, "!MD"
? ndata7 "MFSK16,FSK441,MSK144" ;6文字
#FontSize=9
#Print 777, 512, "!MD"
? End
#Goto *993

*992
#Print 180, 458, "--- End of QSO-DATA(1) ---"
#Exit

;**交信データ3行目**

*993
#Readj *994 ;同じコールサインでなければ*994へ

#FontName="HAM 明朝 Light"
#FontSize=11
#Print 20, 574, "!cp" ;相手局コールサイン印刷
#FontName="ＭＳ明朝"
? DXST! ;相手局が海外局ではなく
? Potbl ;移動運用で
? Space! "!QT" ;QTHが入力されていたら
#FontSize=9
#Print 240, 580, "!QT 移動" ;相手局のQTHを印刷
? End

#FontSize=11
#Print 20, 628, "'!Dy" ;交信年
#Print 120, 628, "!DJ." ;交信月
#Print 240, 628, "!Dd" ;交信日
#Print 330, 628, "!TH:!TM" ;交信時分
#Print 660, 628, "!FR" ;交信周波数帯

? ndata7 "AM,FM,SSB,C4FM" ;レポートが2文字のモードは
#Print 535, 628, " !HR" ;Hisレポートの前に１スペース挿入
? ndata7! "AM,FM,SSB,C4FM" ;他のモードは
#Print 535, 628, "!HR" ;Hisレポートそのまま印刷
? End
;
;データモードはレポート欄に"dB"印刷
;
? ndata7 "FT8,FT4,Q65,MSK144,JT65"
#FontSize=8
#Print 603, 628, "dB"
? End
;
;JST/UTC印刷
;
#FontSize=10
? UTC!
#Print 440, 632, "JST"
? UTC
#Print 440, 632, "UTC"
;
; モード別調整印刷
;
#FontSize=10
? ndata7 "CW,AM,FM,SSB,FT8,FT4,Q65" ;2-3文字
#Print 777, 628, " !MD"
? ndata7 "C4FM,SSTV,RTTY,JT44,JT65,JT6M" ;4文字
#Print 777, 628, " !MD"
? ndata7 "PSK31,PSK63" ;5文字
#Print 777, 628, "!MD"
? ndata7 "MFSK16,FSK441,MSK144" ; 6文字
#FontSize=9
#Print 777, 628, "!MD"
? End
#Goto *995

*994
#Print 180, 574, "--- End of QSO-DATA(2) ---"
#Exit

;**交信データ4行目**

*995
#Readj *996 ;同じコールサインでなければ*996へ

#FontName="HAM 明朝 Light"
#FontSize=11
#Print 20, 690, "!cp" ;相手局コールサイン印刷
#FontName="ＭＳ明朝"
? DXST! ;相手局が海外局ではなく
? Potbl ;移動運用で
? Space! "!QT" ;QTHが入力されていたら
#FontSize=9
#Print 240, 696, "!QT 移動" ;相手局のQTHを印刷
? End

#FontSize=11
#Print 20, 744, "'!Dy" ;交信年
#Print 120, 744, "!DJ." ;交信月
#Print 240, 744, "!Dd" ;交信日
#Print 330, 744, "!TH:!TM" ;交信時分
#Print 660, 744, "!FR" ;交信周波数帯

? ndata7 "AM,FM,SSB,C4FM" ;レポートが2文字のモードは
#Print 535, 744, " !HR" ;Hisレポートの前に１スペース挿入
? ndata7! "AM,FM,SSB,C4FM" ;他のモードは
#Print 535, 744, "!HR" ;Hisレポートそのまま印刷
;
;データモードはレポート欄に"dB"印刷
;
? ndata7 "FT8,FT4,Q65,MSK144,JT65"
#FontSize=8
#Print 603, 733, "dB"
? End
;
;JST/UTC印刷
;
#FontSize=10
? UTC!
#Print 440, 748, "JST"
? UTC
#Print 440, 748, "UTC"
;
; モード別調整印刷
;
#FontSize=10
? ndata7 "CW,AM,FM,SSB,FT8,FT4,Q65" ;2-3文字
#Print 777, 744, " !MD"
? ndata7 "C4FM,SSTV,RTTY,JT44,JT65,JT6M" ;4文字
#Print 777, 744, " !MD"
? ndata7 "PSK31,PSK63" ;5文字
#Print 777, 744, "!MD"
? ndata7 "MFSK16,FSK441,MSK144" ;6文字
#FontSize=9
#Print 777, 744, "!MD"
? End
#Goto *997

*996
#FontSize=10
#Print 180, 690, "--- End of QSO-DATA(3) ---"
#Exit

;**交信データ5行目**

*997
#Readj *998 ;同じコールサインでなければ*998へ

#FontName="HAM 明朝 Light"
#FontSize=11
#Print 20, 806, "!cp" ;相手局コールサイン印刷
#FontName="ＭＳ明朝"
? DXST! ;相手局が海外局ではなく
? Potbl ;移動運用で
? Space! "!QT" ;QTHが入力されていたら
#FontSize=9
#Print 240, 812, "!QT 移動" ;相手局のQTHを印刷
? End

#FontSize=11
#Print 20, 860, "'!Dy" ;交信年
#Print 120, 860, "!DJ." ;交信月
#Print 240, 860, "!Dd" ;交信日
#Print 330, 860, "!TH:!TM" ;交信時、分
#Print 660, 860, "!FR" ;交信周波数帯

? ndata7 "AM,FM,SSB,C4FM" ;レポートが2文字のモードは
#Print 535, 860, " !HR" ;Hisレポートの前に１スペース挿入
? ndata7! "AM,FM,SSB,C4FM" ;他のモードは
#Print 535, 860, "!HR" ;Hisレポートそのまま印刷
;
;データモードはレポート欄に"dB"印刷
;
? ndata7 "FT8,FT4,Q65,MSK144,JT65"
#FontSize=8
#Print 603, 860, "dB"
? End
;
;JST/UTC印刷
;
#FontSize=10
? UTC!
#Print 440, 864, "JST"
? UTC
#Print 440, 864, "UTC"
;
; モード別調整印刷
;
? ndata7 "CW,AM,FM,SSB,FT8,FT4,Q65" ;2-3文字
#Print 777, 860, " !MD"
? ndata7 "C4FM,SSTV,RTTY,JT44,JT65,JT6M" ;4文字
#Print 777, 860, " !MD"
? ndata7 "PSK31,PSK63" ;5文字
#Print 777, 860, "!MD"
? ndata7 "MFSK16,FSK441,MSK144" ; 6文字
#FontSize=9
#Print 777, 860, "!MD"
? End
#Exit

*998
#FontSize=10
#Print 180, 806, "--- End of QSO-DATA(4) ---"
#Exit

２　交信ごとに自局移動地を表記するスタイル

　交信データの枠を広げて、交信毎に自局移動地を表示できるようにしました。
2ポイント移動など自局移動地が頻繁に切り変わる運用に対応しています。
マクロファイル"5QSO-SA.QSL"はここからダウンロードできます。

マクロの"=====自局リグ・コールサイン・QTHなど印刷====="以下を修正してご利用ください。

△交信データの区切り線が印刷できなかったので修正しました '23/12/09

自局が移動の場合
Remarks2欄に以下の記述があれば移動とみなして交信ごとに(自局のコールサイン)(記述された文字列)+"移動"を表示します

記述方法
　%/(半角数字0～9,P) 移動地等%

　記述例
%/1 神奈川県相模原市南区 JCC111003%

＊記述に"%/"があれば移動していると
　みなします
＊相手局の/以降が4文字以上の場合は
　移動地の表記と重なってしまいます
　ログQTH欄の前方に空白を入れて回避
　できます
＊相手局/QRPはハムログの仕様上、移動
　とはみなされません
＊相手局には"移動"が付記されます

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　(C)JA1VZV 2023.12
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　

トップアイコン

トップページへもどる